# Copyright 2022 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pigweed.gni")

import("$dir_pw_build/target_types.gni")

group("basic_executable") {
  if (pw_rust_USE_STD) {
    deps = [
      ":hello",
      ":hello_pw_log",
      ":test_hello",
      ":test_proc_macro",
    ]
  } else {
    deps = [ ":hello_pw_log" ]
  }
}

pw_rust_executable("hello") {
  sources = [
    "main.rs",
    "other.rs",
  ]
  deps = [
    ":a",
    ":c",
    ":proc_macro",
  ]
}

# `hello_pw_log` is a re-implementation of `hello` with no_std support.
# It uses `pw_log()` instead of `println!()`.
pw_rust_executable("hello_pw_log") {
  sources = [
    "bin/hello_pw_log/main.rs",
    "other.rs",
  ]
  deps = [
    ":a",
    ":c",
    ":proc_macro",
  ]
  if (pw_rust_USE_STD) {
    features = [ "std" ]
  }
}

pw_rust_test("test_hello") {
  sources = [
    "main.rs",
    "other.rs",
  ]
  deps = [
    ":a",
    ":c",
    ":proc_macro",
  ]
}

# The dep chain hello->a->b will exercise the functionality of both direct and
# transitive deps for A
pw_rust_library("a") {
  crate_root = "a/lib.rs"
  sources = [ "a/lib.rs" ]
  deps = [ ":b" ]
  if (pw_rust_USE_STD) {
    features = [ "std" ]
  }
}

pw_rust_library("b") {
  crate_root = "b/lib.rs"
  sources = [ "b/lib.rs" ]
  deps = [ ":c" ]
  if (pw_rust_USE_STD) {
    features = [ "std" ]
  }
}

pw_rust_library("c") {
  crate_root = "c/lib.rs"
  sources = [ "c/lib.rs" ]
  if (pw_rust_USE_STD) {
    features = [ "std" ]
  }
}

pw_rust_proc_macro("proc_macro") {
  crate_root = "proc_macro/lib.rs"
  sources = [ "proc_macro/lib.rs" ]
}

pw_rust_test("test_proc_macro") {
  sources = [ "proc_macro/test.rs" ]
  deps = [ ":proc_macro" ]
}