1# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
2# file Copyright.txt or https://cmake.org/licensing for details.
3
4
5macro(_cmake_find_compiler lang)
6  # Use already-enabled languages for reference.
7  get_property(_languages GLOBAL PROPERTY ENABLED_LANGUAGES)
8  list(REMOVE_ITEM _languages "${lang}")
9
10  if(CMAKE_${lang}_COMPILER_INIT)
11    # Search only for the specified compiler.
12    set(CMAKE_${lang}_COMPILER_LIST "${CMAKE_${lang}_COMPILER_INIT}")
13  else()
14    # Re-order the compiler list with preferred vendors first.
15    set(_${lang}_COMPILER_LIST "${CMAKE_${lang}_COMPILER_LIST}")
16    set(CMAKE_${lang}_COMPILER_LIST "")
17    # Prefer vendors of compilers from reference languages.
18    foreach(l ${_languages})
19      list(APPEND CMAKE_${lang}_COMPILER_LIST
20        ${_${lang}_COMPILER_NAMES_${CMAKE_${l}_COMPILER_ID}})
21    endforeach()
22    # Prefer vendors based on the platform.
23    list(APPEND CMAKE_${lang}_COMPILER_LIST ${CMAKE_${lang}_COMPILER_NAMES})
24    # Append the rest of the list and remove duplicates.
25    list(APPEND CMAKE_${lang}_COMPILER_LIST ${_${lang}_COMPILER_LIST})
26    unset(_${lang}_COMPILER_LIST)
27    list(REMOVE_DUPLICATES CMAKE_${lang}_COMPILER_LIST)
28    if(CMAKE_${lang}_COMPILER_EXCLUDE)
29      list(REMOVE_ITEM CMAKE_${lang}_COMPILER_LIST
30        ${CMAKE_${lang}_COMPILER_EXCLUDE})
31    endif()
32  endif()
33
34  # Look for directories containing compilers of reference languages.
35  set(_${lang}_COMPILER_HINTS "${CMAKE_${lang}_COMPILER_HINTS}")
36  foreach(l ${_languages})
37    if(CMAKE_${l}_COMPILER AND IS_ABSOLUTE "${CMAKE_${l}_COMPILER}")
38      get_filename_component(_hint "${CMAKE_${l}_COMPILER}" PATH)
39      if(IS_DIRECTORY "${_hint}")
40        list(APPEND _${lang}_COMPILER_HINTS "${_hint}")
41      endif()
42      unset(_hint)
43    endif()
44  endforeach()
45
46  # Find the compiler.
47  if(_${lang}_COMPILER_HINTS)
48    # Prefer directories containing compilers of reference languages.
49    list(REMOVE_DUPLICATES _${lang}_COMPILER_HINTS)
50    find_program(CMAKE_${lang}_COMPILER
51      NAMES ${CMAKE_${lang}_COMPILER_LIST}
52      PATHS ${_${lang}_COMPILER_HINTS}
53      NO_DEFAULT_PATH
54      DOC "${lang} compiler")
55  endif()
56  if(CMAKE_HOST_WIN32 AND CMAKE_GENERATOR MATCHES "Ninja")
57    # On Windows command-line builds, the Makefile generators each imply
58    # a preferred compiler tool.  The Ninja generator does not imply a
59    # compiler tool, so use the compiler that occurs first in PATH.
60    find_program(CMAKE_${lang}_COMPILER
61      NAMES ${CMAKE_${lang}_COMPILER_LIST}
62      NAMES_PER_DIR
63      DOC "${lang} compiler"
64      NO_PACKAGE_ROOT_PATH
65      NO_CMAKE_PATH
66      NO_CMAKE_ENVIRONMENT_PATH
67      NO_CMAKE_SYSTEM_PATH
68      )
69  endif()
70  find_program(CMAKE_${lang}_COMPILER NAMES ${CMAKE_${lang}_COMPILER_LIST} DOC "${lang} compiler")
71  if(_CMAKE_${lang}_COMPILER_PATHS)
72    # As a last fall-back, search in language-specific paths
73    find_program(CMAKE_${lang}_COMPILER
74      NAMES ${CMAKE_${lang}_COMPILER_LIST}
75      NAMES_PER_DIR
76      PATHS ${_CMAKE_${lang}_COMPILER_PATHS}
77      DOC "${lang} compiler"
78      NO_DEFAULT_PATH
79      )
80  endif()
81  if(CMAKE_${lang}_COMPILER_INIT AND NOT CMAKE_${lang}_COMPILER)
82    set_property(CACHE CMAKE_${lang}_COMPILER PROPERTY VALUE "${CMAKE_${lang}_COMPILER_INIT}")
83  endif()
84  unset(_${lang}_COMPILER_HINTS)
85  unset(_languages)
86
87  # Look for a make tool provided by Xcode
88  if(CMAKE_HOST_APPLE)
89    macro(_query_xcrun compiler_name result_var_keyword result_var)
90      if(NOT "x${result_var_keyword}" STREQUAL "xRESULT_VAR")
91        message(FATAL_ERROR "Bad arguments to macro")
92      endif()
93      execute_process(COMMAND xcrun --find ${compiler_name}
94        OUTPUT_VARIABLE _xcrun_out OUTPUT_STRIP_TRAILING_WHITESPACE
95        ERROR_VARIABLE _xcrun_err)
96      set("${result_var}" "${_xcrun_out}")
97    endmacro()
98
99    set(xcrun_result)
100    if (CMAKE_${lang}_COMPILER MATCHES "^/usr/bin/(.+)$")
101      _query_xcrun("${CMAKE_MATCH_1}" RESULT_VAR xcrun_result)
102    elseif (CMAKE_${lang}_COMPILER STREQUAL "CMAKE_${lang}_COMPILER-NOTFOUND")
103      foreach(comp ${CMAKE_${lang}_COMPILER_LIST})
104        _query_xcrun("${comp}" RESULT_VAR xcrun_result)
105        if(xcrun_result)
106          break()
107        endif()
108      endforeach()
109    endif()
110    if (xcrun_result)
111      set_property(CACHE CMAKE_${lang}_COMPILER PROPERTY VALUE "${xcrun_result}")
112    endif()
113  endif()
114endmacro()
115
116macro(_cmake_find_compiler_path lang)
117  if(CMAKE_${lang}_COMPILER)
118    # we only get here if CMAKE_${lang}_COMPILER was specified using -D or a pre-made CMakeCache.txt
119    # (e.g. via ctest) or set in CMAKE_TOOLCHAIN_FILE
120    # if CMAKE_${lang}_COMPILER is a list, use the first item as
121    # CMAKE_${lang}_COMPILER and the rest as CMAKE_${lang}_COMPILER_ARG1
122    set(CMAKE_${lang}_COMPILER_ARG1 "${CMAKE_${lang}_COMPILER}")
123    list(POP_FRONT CMAKE_${lang}_COMPILER_ARG1 CMAKE_${lang}_COMPILER)
124    list(JOIN CMAKE_${lang}_COMPILER_ARG1 " " CMAKE_${lang}_COMPILER_ARG1)
125
126    # find the compiler in the PATH if necessary
127    # if compiler (and arguments) comes from cache then synchronize cache with updated CMAKE_<LANG>_COMPILER
128    get_filename_component(_CMAKE_USER_${lang}_COMPILER_PATH "${CMAKE_${lang}_COMPILER}" PATH)
129    if(NOT _CMAKE_USER_${lang}_COMPILER_PATH)
130      find_program(CMAKE_${lang}_COMPILER_WITH_PATH NAMES ${CMAKE_${lang}_COMPILER})
131      if(CMAKE_${lang}_COMPILER_WITH_PATH)
132        set(CMAKE_${lang}_COMPILER ${CMAKE_${lang}_COMPILER_WITH_PATH})
133        get_property(_CMAKE_${lang}_COMPILER_CACHED CACHE CMAKE_${lang}_COMPILER PROPERTY TYPE)
134        if(_CMAKE_${lang}_COMPILER_CACHED)
135          set(CMAKE_${lang}_COMPILER "${CMAKE_${lang}_COMPILER}" CACHE STRING "${lang} compiler" FORCE)
136        endif()
137        unset(_CMAKE_${lang}_COMPILER_CACHED)
138      endif()
139      unset(CMAKE_${lang}_COMPILER_WITH_PATH CACHE)
140    elseif (EXISTS ${CMAKE_${lang}_COMPILER})
141      get_property(_CMAKE_${lang}_COMPILER_CACHED CACHE CMAKE_${lang}_COMPILER PROPERTY TYPE)
142      if(_CMAKE_${lang}_COMPILER_CACHED)
143        set(CMAKE_${lang}_COMPILER "${CMAKE_${lang}_COMPILER}" CACHE STRING "${lang} compiler" FORCE)
144      endif()
145      unset(_CMAKE_${lang}_COMPILER_CACHED)
146    endif()
147  endif()
148endmacro()
149
150function(_cmake_find_compiler_sysroot lang)
151  if(CMAKE_${lang}_COMPILER_ID STREQUAL "GNU")
152    execute_process(COMMAND "${CMAKE_${lang}_COMPILER}" -print-sysroot
153      OUTPUT_STRIP_TRAILING_WHITESPACE
154      OUTPUT_VARIABLE _cmake_sysroot_run_out
155      ERROR_VARIABLE _cmake_sysroot_run_err)
156
157    if(_cmake_sysroot_run_out AND NOT _cmake_sysroot_run_err
158        AND NOT _cmake_sysroot_run_out STREQUAL "/"
159        AND IS_DIRECTORY "${_cmake_sysroot_run_out}/usr")
160      file(TO_CMAKE_PATH "${_cmake_sysroot_run_out}/usr" _cmake_sysroot_run_out_usr)
161      set(CMAKE_${lang}_COMPILER_SYSROOT "${_cmake_sysroot_run_out_usr}" PARENT_SCOPE)
162    else()
163      set(CMAKE_${lang}_COMPILER_SYSROOT "" PARENT_SCOPE)
164    endif()
165  endif()
166endfunction()
167