1# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
2# file Copyright.txt or https://cmake.org/licensing for details.
3
4
5# This module is shared by multiple languages; use include blocker.
6if(__LINUX_COMPILER_INTEL)
7  return()
8endif()
9set(__LINUX_COMPILER_INTEL 1)
10
11if(NOT XIAR)
12  set(_intel_xiar_hints)
13  foreach(lang C CXX Fortran)
14    if(IS_ABSOLUTE "${CMAKE_${lang}_COMPILER}")
15      get_filename_component(_hint "${CMAKE_${lang}_COMPILER}" PATH)
16      list(APPEND _intel_xiar_hints ${_hint})
17    endif()
18  endforeach()
19  find_program(XIAR NAMES xiar HINTS ${_intel_xiar_hints})
20  mark_as_advanced(XIAR)
21endif()
22
23macro(__linux_compiler_intel lang)
24  set(CMAKE_${lang}_COMPILE_OPTIONS_PIC "-fPIC")
25  set(CMAKE_${lang}_COMPILE_OPTIONS_PIE "-fPIE")
26  set(_CMAKE_${lang}_PIE_MAY_BE_SUPPORTED_BY_LINKER NO)
27  if (NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 13.0)
28    set(_CMAKE_${lang}_PIE_MAY_BE_SUPPORTED_BY_LINKER YES)
29    set(CMAKE_${lang}_LINK_OPTIONS_PIE ${CMAKE_${lang}_COMPILE_OPTIONS_PIE} "-pie")
30    set(CMAKE_${lang}_LINK_OPTIONS_NO_PIE "-no-pie")
31  endif()
32  set(CMAKE_SHARED_LIBRARY_${lang}_FLAGS "-fPIC")
33  set(CMAKE_SHARED_LIBRARY_CREATE_${lang}_FLAGS "-shared")
34
35  # We pass this for historical reasons.  Projects may have
36  # executables that use dlopen but do not set ENABLE_EXPORTS.
37  set(CMAKE_SHARED_LIBRARY_LINK_${lang}_FLAGS "-rdynamic")
38
39  set(CMAKE_${lang}_LINKER_WRAPPER_FLAG "-Wl,")
40  set(CMAKE_${lang}_LINKER_WRAPPER_FLAG_SEP ",")
41
42  set(_CMAKE_${lang}_IPO_SUPPORTED_BY_CMAKE YES)
43
44  if(XIAR)
45    # INTERPROCEDURAL_OPTIMIZATION
46    set(CMAKE_${lang}_COMPILE_OPTIONS_IPO -ipo)
47    set(CMAKE_${lang}_CREATE_STATIC_LIBRARY_IPO
48      "${XIAR} cr <TARGET> <LINK_FLAGS> <OBJECTS> "
49      "${XIAR} -s <TARGET> ")
50    set(_CMAKE_${lang}_IPO_MAY_BE_SUPPORTED_BY_COMPILER YES)
51    set(_CMAKE_${lang}_IPO_LEGACY_BEHAVIOR YES)
52  else()
53    set(_CMAKE_${lang}_IPO_MAY_BE_SUPPORTED_BY_COMPILER NO)
54  endif()
55
56  if(NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 12.0)
57    set(CMAKE_${lang}_COMPILE_OPTIONS_VISIBILITY "-fvisibility=")
58  endif()
59endmacro()
60