xref: /aosp_15_r20/external/mesa3d/src/gallium/targets/teflon/meson.build (revision 6104692788411f58d303aa86923a9ff6ecaded22) 
1libteflon = shared_library(
2  'teflon',
3  [ 'teflon_target.c' ],
4  include_directories : [ inc_src, inc_util, inc_include, inc_gallium, inc_gallium_aux, inc_gallium_winsys, inc_gallium_drivers ],
5  link_whole : [ libteflon_st ],
6  link_with : [libpipe_loader_static, libws_null, libwsw, libswdri, libswkmsdri, libgallium ],
7  gnu_symbol_visibility : 'hidden',
8  link_args : ld_args_build_id,
9  dependencies : [
10    driver_etnaviv,
11    idep_nir,
12    idep_mesautil,
13  ],
14  install : true,
15)
16
17if with_tests
18  tensorflow_lite = shared_library(
19    'tensorflow-lite',
20    [ 'tflite-stub.c' ],
21    include_directories : [ inc_include ],
22    install : false,
23  )
24
25  tflite_flatbuffer_h_name = 'tflite-schema-v2.15.0_generated.h'
26  tflite_flatbuffer_h = custom_target('tflite_flatbuffer.h',
27    output: tflite_flatbuffer_h_name,
28    input: 'tflite-schema-v2.15.0.fbs',
29    command : [
30      prog_flatc,
31      '--cpp',
32      '--cpp-ptr-type', 'std::shared_ptr',
33      '--gen-object-api',
34      '-o', meson.current_build_dir(),
35      '@INPUT@'
36    ],
37  )
38
39  executable(
40    'test_teflon',
41    'test_teflon.cpp',
42    'test_executor.cpp',
43    tflite_flatbuffer_h,
44    dependencies : [ idep_mesautil, idep_gtest ],
45    link_with : [ tensorflow_lite ],
46    include_directories : [ inc_include ],
47  )
48endif
49