xref: /aosp_15_r20/external/perfmark/java7/build.gradle (revision 27e8546d0ef5f99cf83d5252272c7dd38d18d29a)

description = "PerfMark Java7 API"
ext.moduleName = "io.perfmark.javaseven"
ext.jdkVersion = JavaVersion.VERSION_1_7

compileJava {
    sourceCompatibility = jdkVersion
    targetCompatibility = jdkVersion

    options.compilerArgs.add("-Xlint:-options")
}

sourceSets {
    jmh {}
}


compileJmhJava {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
    javaCompiler = javaToolchains.compilerFor({
        languageVersion = JavaLanguageVersion.of("11")
    })
    options.errorprone.excludedPaths.set(".*/build/generated/sources/annotationProcessor/.*")
}

dependencies {
    implementation project(':perfmark-impl')
    compileOnly libs.jsr305

    jmhImplementation project(':perfmark-api'),
            project(':perfmark-impl'),
            project(':perfmark-java7'),
            project(':perfmark-testing')
    jmhImplementation libs.junit
    jmhImplementation libs.jmhcore
    jmhAnnotationProcessor libs.jmhanno
}

javadoc {
    exclude 'io/perfmark/java7**'
}

jar {
    exclude 'io/perfmark/java7/Internal*'
}

tasks.register('jmh', Test) {
    description = 'Runs integration tests.'
    group = 'stress'

    testClassesDirs = sourceSets.jmh.output.classesDirs
    classpath = sourceSets.jmh.runtimeClasspath

    javaLauncher = javaToolchains.launcherFor({
        languageVersion = JavaLanguageVersion.of("16")
    })
    //shouldRunAfter test
}