xref: /aosp_15_r20/external/angle/src/tests/restricted_traces/BUILD.gn (revision 8975f5c5ed3d1c378011245431ada316dfb6f244) 
1# Copyright 2020 The ANGLE Project Authors. All rights reserved.
2# Use of this source code is governed by a BSD-style license that can be
3# found in the LICENSE file.
4#
5# Contains the build rules for confidential trace tests.
6
7import("../../../gni/angle.gni")
8import("../angle_traces.gni")
9
10angle_trace_libs("angle_restricted_traces") {
11  json_path = "restricted_traces.json"
12  if (angle_restricted_traces != []) {
13    trace_list = angle_restricted_traces
14  } else {
15    _trace_json = read_file(json_path, "json")
16    trace_list = _trace_json.traces
17  }
18}
19
20group("goldctl") {
21  data = []
22
23  # Because this links to a CIPD dependency, which is a symlink on Unix
24  # platforms, refer to the actual executable rather than the whole directory;
25  # copying the whole directory doesn't work, at least with "mb.py zip".
26  if (is_win) {
27    data += [ "//tools/skia_goldctl/win/goldctl.exe" ]
28  } else if (is_mac) {
29    data += [
30      "//tools/skia_goldctl/mac_amd64/goldctl",
31      "//tools/skia_goldctl/mac_arm64/goldctl",
32    ]
33  } else {
34    data += [ "//tools/skia_goldctl/linux/goldctl" ]
35  }
36}
37
38group("angle_restricted_trace_gold_tests") {
39  testonly = true
40  data_deps = [
41    ":goldctl",
42    "$angle_root/src/tests:angle_system_info_test",
43    "$angle_root/src/tests:angle_trace_perf_tests",
44  ]
45  data = [
46    "restricted_trace_gold_tests.py",
47    "restricted_traces.json",
48    "../py_utils/android_helper.py",
49    "../py_utils/angle_path_util.py",
50    "../py_utils/angle_test_util.py",
51    "../py_utils/skia_gold/",
52    "//build/skia_gold_common/",
53    "//testing/scripts/common.py",
54    "//testing/xvfb.py",
55  ]
56}
57