xref: /aosp_15_r20/external/cronet/third_party/libc++/src/cmake/config-ix.cmake (revision 6777b5387eb2ff775bb5750e3f5d96f37fb7352b) 
1include(CMakePushCheckState)
2include(CheckLibraryExists)
3include(CheckSymbolExists)
4include(LLVMCheckCompilerLinkerFlag)
5include(CheckCCompilerFlag)
6include(CheckCXXCompilerFlag)
7include(CheckCSourceCompiles)
8
9# The compiler driver may be implicitly trying to link against libunwind.
10# This is normally ok (libcxx relies on an unwinder), but if libunwind is
11# built in the same cmake invocation as libcxx and we've got
12# LIBCXXABI_USE_LLVM_UNWINDER set, we'd be linking against the just-built
13# libunwind (and the compiler implicit -lunwind wouldn't succeed as the newly
14# built libunwind isn't installed yet). For those cases, it'd be good to
15# link with --uwnindlib=none. Check if that option works.
16llvm_check_compiler_linker_flag(C "--unwindlib=none" CXX_SUPPORTS_UNWINDLIB_EQ_NONE_FLAG)
17
18if (NOT LIBCXX_USE_COMPILER_RT)
19  if(WIN32 AND NOT MINGW)
20    set(LIBCXX_HAS_GCC_S_LIB NO)
21  else()
22    if(ANDROID)
23      check_library_exists(gcc __gcc_personality_v0 "" LIBCXX_HAS_GCC_LIB)
24    else()
25      check_library_exists(gcc_s __gcc_personality_v0 "" LIBCXX_HAS_GCC_S_LIB)
26    endif()
27  endif()
28endif()
29
30# libc++ is using -nostdlib++ at the link step when available,
31# otherwise -nodefaultlibs is used. We want all our checks to also
32# use one of these options, otherwise we may end up with an inconsistency between
33# the flags we think we require during configuration (if the checks are
34# performed without one of those options) and the flags that are actually
35# required during compilation (which has the -nostdlib++ or -nodefaultlibs). libc is
36# required for the link to go through. We remove sanitizers from the
37# configuration checks to avoid spurious link errors.
38
39check_cxx_compiler_flag(-nostdlib++ CXX_SUPPORTS_NOSTDLIBXX_FLAG)
40if (CXX_SUPPORTS_NOSTDLIBXX_FLAG)
41  set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -nostdlib++")
42else()
43  check_c_compiler_flag(-nodefaultlibs C_SUPPORTS_NODEFAULTLIBS_FLAG)
44  if (C_SUPPORTS_NODEFAULTLIBS_FLAG)
45    set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -nodefaultlibs")
46  endif()
47endif()
48
49# Only link against compiler-rt manually if we use -nodefaultlibs, since
50# otherwise the compiler will do the right thing on its own.
51if (NOT CXX_SUPPORTS_NOSTDLIBXX_FLAG AND C_SUPPORTS_NODEFAULTLIBS_FLAG)
52  if (LIBCXX_USE_COMPILER_RT)
53    include(HandleCompilerRT)
54    find_compiler_rt_library(builtins LIBCXX_BUILTINS_LIBRARY
55                             FLAGS ${LIBCXX_COMPILE_FLAGS})
56    if (LIBCXX_BUILTINS_LIBRARY)
57      list(APPEND CMAKE_REQUIRED_LIBRARIES "${LIBCXX_BUILTINS_LIBRARY}")
58    else()
59      message(WARNING "Could not find builtins library from libc++")
60    endif()
61  elseif (LIBCXX_HAS_GCC_LIB)
62    list(APPEND CMAKE_REQUIRED_LIBRARIES gcc)
63  elseif (LIBCXX_HAS_GCC_S_LIB)
64    list(APPEND CMAKE_REQUIRED_LIBRARIES gcc_s)
65  endif ()
66  if (MINGW)
67    # Mingw64 requires quite a few "C" runtime libraries in order for basic
68    # programs to link successfully with -nodefaultlibs.
69    if (LIBCXX_USE_COMPILER_RT)
70      set(MINGW_RUNTIME ${LIBCXX_BUILTINS_LIBRARY})
71    else ()
72      set(MINGW_RUNTIME gcc_s gcc)
73    endif()
74    set(MINGW_LIBRARIES mingw32 ${MINGW_RUNTIME} moldname mingwex msvcrt advapi32
75                        shell32 user32 kernel32 mingw32 ${MINGW_RUNTIME}
76                        moldname mingwex msvcrt)
77    list(APPEND CMAKE_REQUIRED_LIBRARIES ${MINGW_LIBRARIES})
78  endif()
79endif()
80
81if (CXX_SUPPORTS_NOSTDLIBXX_FLAG OR C_SUPPORTS_NODEFAULTLIBS_FLAG)
82  if (CMAKE_C_FLAGS MATCHES -fsanitize OR CMAKE_CXX_FLAGS MATCHES -fsanitize)
83    set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fno-sanitize=all")
84  endif ()
85  if (CMAKE_C_FLAGS MATCHES -fsanitize-coverage OR CMAKE_CXX_FLAGS MATCHES -fsanitize-coverage)
86    set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fsanitize-coverage=0")
87  endif ()
88endif ()
89
90# Check compiler pragmas
91if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
92  cmake_push_check_state()
93  set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror=unknown-pragmas")
94  check_c_source_compiles("
95#pragma comment(lib, \"c\")
96int main(void) { return 0; }
97" C_SUPPORTS_COMMENT_LIB_PRAGMA)
98  cmake_pop_check_state()
99endif()
100
101check_symbol_exists(__PICOLIBC__ "string.h" PICOLIBC)
102
103# Check libraries
104if(WIN32 AND NOT MINGW)
105  # TODO(compnerd) do we want to support an emulation layer that allows for the
106  # use of pthread-win32 or similar libraries to emulate pthreads on Windows?
107  set(LIBCXX_HAS_PTHREAD_LIB NO)
108  set(LIBCXX_HAS_RT_LIB NO)
109  set(LIBCXX_HAS_ATOMIC_LIB NO)
110elseif(APPLE)
111  set(LIBCXX_HAS_PTHREAD_LIB NO)
112  set(LIBCXX_HAS_RT_LIB NO)
113  set(LIBCXX_HAS_ATOMIC_LIB NO)
114elseif(FUCHSIA)
115  set(LIBCXX_HAS_PTHREAD_LIB NO)
116  set(LIBCXX_HAS_RT_LIB NO)
117  check_library_exists(atomic __atomic_fetch_add_8 "" LIBCXX_HAS_ATOMIC_LIB)
118elseif(ANDROID)
119  set(LIBCXX_HAS_PTHREAD_LIB NO)
120  set(LIBCXX_HAS_RT_LIB NO)
121  set(LIBCXX_HAS_ATOMIC_LIB NO)
122elseif(PICOLIBC)
123  set(LIBCXX_HAS_PTHREAD_LIB NO)
124  set(LIBCXX_HAS_RT_LIB NO)
125  set(LIBCXX_HAS_ATOMIC_LIB NO)
126else()
127  check_library_exists(pthread pthread_create "" LIBCXX_HAS_PTHREAD_LIB)
128  check_library_exists(rt clock_gettime "" LIBCXX_HAS_RT_LIB)
129  check_library_exists(atomic __atomic_fetch_add_8 "" LIBCXX_HAS_ATOMIC_LIB)
130endif()
131