1# This is a basic version file for the Config-mode of find_package().
2# It is used by write_basic_package_version_file() as input file for configure_file()
3# to create a version-file which can be installed along a config.cmake file.
4#
5# The created file sets PACKAGE_VERSION_EXACT if the current version string and
6# the requested version string are exactly the same and it sets
7# PACKAGE_VERSION_COMPATIBLE if the current version is equal to the requested version.
8# The tweak version component is ignored.
9# The variable CVF_VERSION must be set before calling configure_file().
10
11
12if (PACKAGE_FIND_VERSION_RANGE)
13  message(AUTHOR_WARNING
14    "`find_package()` specify a version range but the version strategy "
15    "(ExactVersion) of the module `${PACKAGE_FIND_NAME}` is incompatible "
16    "with this request. Only the lower endpoint of the range will be used.")
17endif()
18
19set(PACKAGE_VERSION "@CVF_VERSION@")
20
21if("@CVF_VERSION@" MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+)") # strip the tweak version
22  set(CVF_VERSION_MAJOR "${CMAKE_MATCH_1}")
23  set(CVF_VERSION_MINOR "${CMAKE_MATCH_2}")
24  set(CVF_VERSION_PATCH "${CMAKE_MATCH_3}")
25
26  if(NOT CVF_VERSION_MAJOR VERSION_EQUAL 0)
27    string(REGEX REPLACE "^0+" "" CVF_VERSION_MAJOR "${CVF_VERSION_MAJOR}")
28  endif()
29  if(NOT CVF_VERSION_MINOR VERSION_EQUAL 0)
30    string(REGEX REPLACE "^0+" "" CVF_VERSION_MINOR "${CVF_VERSION_MINOR}")
31  endif()
32  if(NOT CVF_VERSION_PATCH VERSION_EQUAL 0)
33    string(REGEX REPLACE "^0+" "" CVF_VERSION_PATCH "${CVF_VERSION_PATCH}")
34  endif()
35
36  set(CVF_VERSION_NO_TWEAK "${CVF_VERSION_MAJOR}.${CVF_VERSION_MINOR}.${CVF_VERSION_PATCH}")
37else()
38  set(CVF_VERSION_NO_TWEAK "@CVF_VERSION@")
39endif()
40
41if(PACKAGE_FIND_VERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+)") # strip the tweak version
42  set(REQUESTED_VERSION_MAJOR "${CMAKE_MATCH_1}")
43  set(REQUESTED_VERSION_MINOR "${CMAKE_MATCH_2}")
44  set(REQUESTED_VERSION_PATCH "${CMAKE_MATCH_3}")
45
46  if(NOT REQUESTED_VERSION_MAJOR VERSION_EQUAL 0)
47    string(REGEX REPLACE "^0+" "" REQUESTED_VERSION_MAJOR "${REQUESTED_VERSION_MAJOR}")
48  endif()
49  if(NOT REQUESTED_VERSION_MINOR VERSION_EQUAL 0)
50    string(REGEX REPLACE "^0+" "" REQUESTED_VERSION_MINOR "${REQUESTED_VERSION_MINOR}")
51  endif()
52  if(NOT REQUESTED_VERSION_PATCH VERSION_EQUAL 0)
53    string(REGEX REPLACE "^0+" "" REQUESTED_VERSION_PATCH "${REQUESTED_VERSION_PATCH}")
54  endif()
55
56  set(REQUESTED_VERSION_NO_TWEAK
57      "${REQUESTED_VERSION_MAJOR}.${REQUESTED_VERSION_MINOR}.${REQUESTED_VERSION_PATCH}")
58else()
59  set(REQUESTED_VERSION_NO_TWEAK "${PACKAGE_FIND_VERSION}")
60endif()
61
62if(REQUESTED_VERSION_NO_TWEAK STREQUAL CVF_VERSION_NO_TWEAK)
63  set(PACKAGE_VERSION_COMPATIBLE TRUE)
64else()
65  set(PACKAGE_VERSION_COMPATIBLE FALSE)
66endif()
67
68if(PACKAGE_FIND_VERSION STREQUAL PACKAGE_VERSION)
69  set(PACKAGE_VERSION_EXACT TRUE)
70endif()
71
72
73# if the installed project requested no architecture check, don't perform the check
74if("@CVF_ARCH_INDEPENDENT@")
75  return()
76endif()
77
78# if the installed or the using project don't have CMAKE_SIZEOF_VOID_P set, ignore it:
79if("${CMAKE_SIZEOF_VOID_P}" STREQUAL "" OR "@CMAKE_SIZEOF_VOID_P@" STREQUAL "")
80  return()
81endif()
82
83# check that the installed version has the same 32/64bit-ness as the one which is currently searching:
84if(NOT CMAKE_SIZEOF_VOID_P STREQUAL "@CMAKE_SIZEOF_VOID_P@")
85  math(EXPR installedBits "@CMAKE_SIZEOF_VOID_P@ * 8")
86  set(PACKAGE_VERSION "${PACKAGE_VERSION} (${installedBits}bit)")
87  set(PACKAGE_VERSION_UNSUITABLE TRUE)
88endif()
89