1# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
2# file Copyright.txt or https://cmake.org/licensing for details.
3
4
5if(UNIX)
6  set(CMAKE_ASM${ASM_DIALECT}_OUTPUT_EXTENSION .o)
7else()
8  set(CMAKE_ASM${ASM_DIALECT}_OUTPUT_EXTENSION .obj)
9endif()
10
11set(CMAKE_INCLUDE_FLAG_ASM${ASM_DIALECT} "-I")       # -I
12set(CMAKE_BASE_NAME)
13get_filename_component(CMAKE_BASE_NAME "${CMAKE_ASM${ASM_DIALECT}_COMPILER}" NAME_WE)
14
15if("${CMAKE_BASE_NAME}" STREQUAL "as")
16  set(CMAKE_BASE_NAME gas)
17endif()
18
19# Load compiler-specific information.
20set(_INCLUDED_FILE "")
21if(CMAKE_ASM${ASM_DIALECT}_COMPILER_ID)
22  include(Compiler/${CMAKE_ASM${ASM_DIALECT}_COMPILER_ID}-ASM${ASM_DIALECT} OPTIONAL  RESULT_VARIABLE _INCLUDED_FILE)
23endif()
24if(NOT _INCLUDED_FILE)
25  if("ASM${ASM_DIALECT}" STREQUAL "ASM")
26    message(STATUS "Warning: Did not find file Compiler/${CMAKE_ASM${ASM_DIALECT}_COMPILER_ID}-ASM${ASM_DIALECT}")
27  endif()
28  include(Platform/${CMAKE_BASE_NAME} OPTIONAL)
29endif()
30
31if(CMAKE_SYSTEM_PROCESSOR)
32  include(Platform/${CMAKE_EFFECTIVE_SYSTEM_NAME}-${CMAKE_ASM${ASM_DIALECT}_COMPILER_ID}-ASM${ASM_DIALECT}-${CMAKE_SYSTEM_PROCESSOR} OPTIONAL  RESULT_VARIABLE _INCLUDED_FILE)
33  if(NOT _INCLUDED_FILE)
34    include(Platform/${CMAKE_EFFECTIVE_SYSTEM_NAME}-${CMAKE_BASE_NAME}-${CMAKE_SYSTEM_PROCESSOR} OPTIONAL)
35  endif()
36endif()
37
38include(Platform/${CMAKE_EFFECTIVE_SYSTEM_NAME}-${CMAKE_ASM${ASM_DIALECT}_COMPILER_ID}-ASM${ASM_DIALECT} OPTIONAL  RESULT_VARIABLE _INCLUDED_FILE)
39if(NOT _INCLUDED_FILE)
40  include(Platform/${CMAKE_EFFECTIVE_SYSTEM_NAME}-${CMAKE_BASE_NAME} OPTIONAL)
41endif()
42
43# This should be included before the _INIT variables are
44# used to initialize the cache.  Since the rule variables
45# have if blocks on them, users can still define them here.
46# But, it should still be after the platform file so changes can
47# be made to those values.
48
49if(CMAKE_USER_MAKE_RULES_OVERRIDE)
50  # Save the full path of the file so try_compile can use it.
51  include(${CMAKE_USER_MAKE_RULES_OVERRIDE} RESULT_VARIABLE _override)
52  set(CMAKE_USER_MAKE_RULES_OVERRIDE "${_override}")
53endif()
54
55if(CMAKE_USER_MAKE_RULES_OVERRIDE_ASM)
56  # Save the full path of the file so try_compile can use it.
57  include(${CMAKE_USER_MAKE_RULES_OVERRIDE_ASM} RESULT_VARIABLE _override)
58  set(CMAKE_USER_MAKE_RULES_OVERRIDE_ASM "${_override}")
59endif()
60
61# Set default assembler file extensions:
62if(NOT CMAKE_ASM${ASM_DIALECT}_SOURCE_FILE_EXTENSIONS)
63  set(CMAKE_ASM${ASM_DIALECT}_SOURCE_FILE_EXTENSIONS s;S;asm)
64endif()
65
66
67# Support for CMAKE_ASM${ASM_DIALECT}_FLAGS_INIT and friends:
68set(CMAKE_ASM${ASM_DIALECT}_FLAGS_INIT "$ENV{ASM${ASM_DIALECT}FLAGS} ${CMAKE_ASM${ASM_DIALECT}_FLAGS_INIT}")
69
70cmake_initialize_per_config_variable(CMAKE_ASM${ASM_DIALECT}_FLAGS "Flags used by the ASM${ASM_DIALECT} compiler")
71
72if(NOT CMAKE_ASM${ASM_DIALECT}_COMPILE_OBJECT)
73  set(CMAKE_ASM${ASM_DIALECT}_COMPILE_OBJECT "<CMAKE_ASM${ASM_DIALECT}_COMPILER> <DEFINES> <INCLUDES> <FLAGS> -o <OBJECT> -c <SOURCE>")
74endif()
75
76if(NOT CMAKE_ASM${ASM_DIALECT}_CREATE_STATIC_LIBRARY)
77  set(CMAKE_ASM${ASM_DIALECT}_CREATE_STATIC_LIBRARY
78      "<CMAKE_AR> cr <TARGET> <LINK_FLAGS> <OBJECTS> "
79      "<CMAKE_RANLIB> <TARGET>")
80endif()
81
82if(NOT CMAKE_ASM${ASM_DIALECT}_LINK_EXECUTABLE)
83  set(CMAKE_ASM${ASM_DIALECT}_LINK_EXECUTABLE
84    "<CMAKE_ASM${ASM_DIALECT}_COMPILER> <FLAGS> <CMAKE_ASM${ASM_DIALECT}_LINK_FLAGS> <LINK_FLAGS> <OBJECTS> -o <TARGET> <LINK_LIBRARIES>")
85endif()
86
87if(NOT CMAKE_EXECUTABLE_RUNTIME_ASM${ASM_DIALECT}_FLAG)
88  set(CMAKE_EXECUTABLE_RUNTIME_ASM${ASM_DIALECT}_FLAG ${CMAKE_SHARED_LIBRARY_RUNTIME_ASM${ASM_DIALECT}_FLAG})
89endif()
90
91if(NOT CMAKE_EXECUTABLE_RUNTIME_ASM${ASM_DIALECT}_FLAG_SEP)
92  set(CMAKE_EXECUTABLE_RUNTIME_ASM${ASM_DIALECT}_FLAG_SEP ${CMAKE_SHARED_LIBRARY_RUNTIME_ASM${ASM_DIALECT}_FLAG_SEP})
93endif()
94
95if(NOT CMAKE_EXECUTABLE_RPATH_LINK_ASM${ASM_DIALECT}_FLAG)
96  set(CMAKE_EXECUTABLE_RPATH_LINK_ASM${ASM_DIALECT}_FLAG ${CMAKE_SHARED_LIBRARY_RPATH_LINK_ASM${ASM_DIALECT}_FLAG})
97endif()
98
99
100set(CMAKE_ASM${ASM_DIALECT}_INFOMATION_LOADED 1)
101