1# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
2# file Copyright.txt or https://cmake.org/licensing for details.
3
4if(UNIX)
5  set(CMAKE_HIP_OUTPUT_EXTENSION .o)
6else()
7  set(CMAKE_HIP_OUTPUT_EXTENSION .obj)
8endif()
9set(CMAKE_INCLUDE_FLAG_HIP "-I")
10
11# Load compiler-specific information.
12if(CMAKE_HIP_COMPILER_ID)
13  include(Compiler/${CMAKE_HIP_COMPILER_ID}-HIP OPTIONAL)
14endif()
15
16# load the system- and compiler specific files
17if(CMAKE_HIP_COMPILER_ID)
18  # load a hardware specific file, mostly useful for embedded compilers
19  if(CMAKE_SYSTEM_PROCESSOR)
20    include(Platform/${CMAKE_EFFECTIVE_SYSTEM_NAME}-${CMAKE_HIP_COMPILER_ID}-HIP-${CMAKE_SYSTEM_PROCESSOR} OPTIONAL)
21  endif()
22  include(Platform/${CMAKE_EFFECTIVE_SYSTEM_NAME}-${CMAKE_HIP_COMPILER_ID}-HIP OPTIONAL)
23endif()
24
25
26if(NOT CMAKE_SHARED_LIBRARY_RUNTIME_HIP_FLAG)
27  set(CMAKE_SHARED_LIBRARY_RUNTIME_HIP_FLAG ${CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG})
28endif()
29
30if(NOT CMAKE_SHARED_LIBRARY_RUNTIME_HIP_FLAG_SEP)
31  set(CMAKE_SHARED_LIBRARY_RUNTIME_HIP_FLAG_SEP ${CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG_SEP})
32endif()
33
34if(NOT CMAKE_SHARED_LIBRARY_RPATH_LINK_HIP_FLAG)
35  set(CMAKE_SHARED_LIBRARY_RPATH_LINK_HIP_FLAG ${CMAKE_SHARED_LIBRARY_RPATH_LINK_C_FLAG})
36endif()
37
38if(NOT DEFINED CMAKE_EXE_EXPORTS_HIP_FLAG)
39  set(CMAKE_EXE_EXPORTS_HIP_FLAG ${CMAKE_EXE_EXPORTS_C_FLAG})
40endif()
41
42if(NOT DEFINED CMAKE_SHARED_LIBRARY_SONAME_HIP_FLAG)
43  set(CMAKE_SHARED_LIBRARY_SONAME_HIP_FLAG ${CMAKE_SHARED_LIBRARY_SONAME_C_FLAG})
44endif()
45
46if(NOT CMAKE_EXECUTABLE_RUNTIME_HIP_FLAG)
47  set(CMAKE_EXECUTABLE_RUNTIME_HIP_FLAG ${CMAKE_SHARED_LIBRARY_RUNTIME_HIP_FLAG})
48endif()
49
50if(NOT CMAKE_EXECUTABLE_RUNTIME_HIP_FLAG_SEP)
51  set(CMAKE_EXECUTABLE_RUNTIME_HIP_FLAG_SEP ${CMAKE_SHARED_LIBRARY_RUNTIME_HIP_FLAG_SEP})
52endif()
53
54if(NOT CMAKE_EXECUTABLE_RPATH_LINK_HIP_FLAG)
55  set(CMAKE_EXECUTABLE_RPATH_LINK_HIP_FLAG ${CMAKE_SHARED_LIBRARY_RPATH_LINK_HIP_FLAG})
56endif()
57
58if(NOT DEFINED CMAKE_SHARED_LIBRARY_LINK_HIP_WITH_RUNTIME_PATH)
59  set(CMAKE_SHARED_LIBRARY_LINK_HIP_WITH_RUNTIME_PATH ${CMAKE_SHARED_LIBRARY_LINK_C_WITH_RUNTIME_PATH})
60endif()
61
62
63# for most systems a module is the same as a shared library
64# so unless the variable CMAKE_MODULE_EXISTS is set just
65# copy the values from the LIBRARY variables
66if(NOT CMAKE_MODULE_EXISTS)
67  set(CMAKE_SHARED_MODULE_HIP_FLAGS ${CMAKE_SHARED_LIBRARY_HIP_FLAGS})
68  set(CMAKE_SHARED_MODULE_CREATE_HIP_FLAGS ${CMAKE_SHARED_LIBRARY_CREATE_HIP_FLAGS})
69endif()
70
71if(CMAKE_EXECUTABLE_FORMAT STREQUAL "ELF")
72  if(NOT DEFINED CMAKE_HIP_LINK_WHAT_YOU_USE_FLAG)
73    set(CMAKE_HIP_LINK_WHAT_YOU_USE_FLAG "LINKER:--no-as-needed")
74  endif()
75  if(NOT DEFINED CMAKE_LINK_WHAT_YOU_USE_CHECK)
76    set(CMAKE_LINK_WHAT_YOU_USE_CHECK ldd -u -r)
77  endif()
78endif()
79
80# add the flags to the cache based
81# on the initial values computed in the platform/*.cmake files
82# use _INIT variables so that this only happens the first time
83# and you can set these flags in the cmake cache
84set(CMAKE_HIP_FLAGS_INIT "$ENV{HIPFLAGS} ${CMAKE_HIP_FLAGS_INIT}")
85
86cmake_initialize_per_config_variable(CMAKE_HIP_FLAGS "Flags used by the HIP compiler")
87
88if(CMAKE_HIP_STANDARD_LIBRARIES_INIT)
89  set(CMAKE_HIP_STANDARD_LIBRARIES "${CMAKE_HIP_STANDARD_LIBRARIES_INIT}"
90    CACHE STRING "Libraries linked by default with all HIP applications.")
91  mark_as_advanced(CMAKE_HIP_STANDARD_LIBRARIES)
92endif()
93
94if(NOT CMAKE_HIP_COMPILER_LAUNCHER AND DEFINED ENV{CMAKE_HIP_COMPILER_LAUNCHER})
95  set(CMAKE_HIP_COMPILER_LAUNCHER "$ENV{CMAKE_HIP_COMPILER_LAUNCHER}"
96    CACHE STRING "Compiler launcher for HIP.")
97endif()
98
99include(CMakeCommonLanguageInclude)
100
101# now define the following rules:
102# CMAKE_HIP_CREATE_SHARED_LIBRARY
103# CMAKE_HIP_CREATE_SHARED_MODULE
104# CMAKE_HIP_COMPILE_OBJECT
105# CMAKE_HIP_LINK_EXECUTABLE
106
107# create a shared library
108if(NOT CMAKE_HIP_CREATE_SHARED_LIBRARY)
109  set(CMAKE_HIP_CREATE_SHARED_LIBRARY
110      "<CMAKE_HIP_COMPILER> <CMAKE_SHARED_LIBRARY_HIP_FLAGS> <LANGUAGE_COMPILE_FLAGS> <LINK_FLAGS> <CMAKE_SHARED_LIBRARY_CREATE_HIP_FLAGS> <SONAME_FLAG><TARGET_SONAME> -o <TARGET> <OBJECTS> <LINK_LIBRARIES>")
111endif()
112
113# create a shared module copy the shared library rule by default
114if(NOT CMAKE_HIP_CREATE_SHARED_MODULE)
115  set(CMAKE_HIP_CREATE_SHARED_MODULE ${CMAKE_HIP_CREATE_SHARED_LIBRARY})
116endif()
117
118# Create a static archive incrementally for large object file counts.
119if(NOT DEFINED CMAKE_HIP_ARCHIVE_CREATE)
120  set(CMAKE_HIP_ARCHIVE_CREATE "<CMAKE_AR> qc <TARGET> <LINK_FLAGS> <OBJECTS>")
121endif()
122if(NOT DEFINED CMAKE_HIP_ARCHIVE_APPEND)
123  set(CMAKE_HIP_ARCHIVE_APPEND "<CMAKE_AR> q <TARGET> <LINK_FLAGS> <OBJECTS>")
124endif()
125if(NOT DEFINED CMAKE_HIP_ARCHIVE_FINISH)
126  set(CMAKE_HIP_ARCHIVE_FINISH "<CMAKE_RANLIB> <TARGET>")
127endif()
128
129# compile a HIP file into an object file
130if(NOT CMAKE_HIP_COMPILE_OBJECT)
131  set(CMAKE_HIP_COMPILE_OBJECT
132    "<CMAKE_HIP_COMPILER> <DEFINES> <INCLUDES> <FLAGS> -o <OBJECT> ${_CMAKE_COMPILE_AS_HIP_FLAG} -c <SOURCE>")
133endif()
134
135# compile a cu file into an executable
136if(NOT CMAKE_HIP_LINK_EXECUTABLE)
137  set(CMAKE_HIP_LINK_EXECUTABLE
138    "<CMAKE_HIP_COMPILER> <FLAGS> <CMAKE_HIP_LINK_FLAGS> <LINK_FLAGS> <OBJECTS> -o <TARGET> <LINK_LIBRARIES>")
139endif()
140
141set(CMAKE_HIP_INFORMATION_LOADED 1)
142
143# Load the file and find the relevant HIP runtime.
144if(NOT DEFINED _CMAKE_HIP_DEVICE_RUNTIME_TARGET)
145  set(hip-lang_DIR "${CMAKE_HIP_COMPILER_ROCM_ROOT}/lib/cmake/hip-lang")
146  find_package(hip-lang CONFIG QUIET NO_DEFAULT_PATH)
147endif()
148if(DEFINED _CMAKE_HIP_DEVICE_RUNTIME_TARGET)
149  list(APPEND CMAKE_HIP_RUNTIME_LIBRARIES_STATIC ${_CMAKE_HIP_DEVICE_RUNTIME_TARGET})
150  list(APPEND CMAKE_HIP_RUNTIME_LIBRARIES_SHARED ${_CMAKE_HIP_DEVICE_RUNTIME_TARGET})
151endif()
152