1# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
2# file Copyright.txt or https://cmake.org/licensing for details.
3
4#[=======================================================================[.rst:
5CMakePushCheckState
6-------------------
7
8
9
10This module defines three macros: ``CMAKE_PUSH_CHECK_STATE()``
11``CMAKE_POP_CHECK_STATE()`` and ``CMAKE_RESET_CHECK_STATE()`` These macros can
12be used to save, restore and reset (i.e., clear contents) the state of
13the variables ``CMAKE_REQUIRED_FLAGS``, ``CMAKE_REQUIRED_DEFINITIONS``,
14``CMAKE_REQUIRED_LINK_OPTIONS``, ``CMAKE_REQUIRED_LIBRARIES``,
15``CMAKE_REQUIRED_INCLUDES`` and ``CMAKE_EXTRA_INCLUDE_FILES`` used by the
16various Check-files coming with CMake, like e.g. ``check_function_exists()``
17etc.
18The variable contents are pushed on a stack, pushing multiple times is
19supported.  This is useful e.g.  when executing such tests in a Find-module,
20where they have to be set, but after the Find-module has been executed they
21should have the same value as they had before.
22
23``CMAKE_PUSH_CHECK_STATE()`` macro receives optional argument ``RESET``.
24Whether it's specified, ``CMAKE_PUSH_CHECK_STATE()`` will set all
25``CMAKE_REQUIRED_*`` variables to empty values, same as
26``CMAKE_RESET_CHECK_STATE()`` call will do.
27
28Usage:
29
30.. code-block:: cmake
31
32   cmake_push_check_state(RESET)
33   set(CMAKE_REQUIRED_DEFINITIONS -DSOME_MORE_DEF)
34   check_function_exists(...)
35   cmake_reset_check_state()
36   set(CMAKE_REQUIRED_DEFINITIONS -DANOTHER_DEF)
37   check_function_exists(...)
38   cmake_pop_check_state()
39#]=======================================================================]
40
41macro(CMAKE_RESET_CHECK_STATE)
42
43  set(CMAKE_EXTRA_INCLUDE_FILES)
44  set(CMAKE_REQUIRED_INCLUDES)
45  set(CMAKE_REQUIRED_DEFINITIONS)
46  set(CMAKE_REQUIRED_LINK_OPTIONS)
47  set(CMAKE_REQUIRED_LIBRARIES)
48  set(CMAKE_REQUIRED_FLAGS)
49  set(CMAKE_REQUIRED_QUIET)
50
51endmacro()
52
53macro(CMAKE_PUSH_CHECK_STATE)
54
55  if(NOT DEFINED _CMAKE_PUSH_CHECK_STATE_COUNTER)
56    set(_CMAKE_PUSH_CHECK_STATE_COUNTER 0)
57  endif()
58
59  math(EXPR _CMAKE_PUSH_CHECK_STATE_COUNTER "${_CMAKE_PUSH_CHECK_STATE_COUNTER}+1")
60
61  set(_CMAKE_EXTRA_INCLUDE_FILES_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER}    ${CMAKE_EXTRA_INCLUDE_FILES})
62  set(_CMAKE_REQUIRED_INCLUDES_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER}      ${CMAKE_REQUIRED_INCLUDES})
63  set(_CMAKE_REQUIRED_DEFINITIONS_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER}   ${CMAKE_REQUIRED_DEFINITIONS})
64  set(_CMAKE_REQUIRED_LINK_OPTIONS_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER}  ${CMAKE_REQUIRED_LINK_OPTIONS})
65  set(_CMAKE_REQUIRED_LIBRARIES_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER}     ${CMAKE_REQUIRED_LIBRARIES})
66  set(_CMAKE_REQUIRED_FLAGS_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER}         ${CMAKE_REQUIRED_FLAGS})
67  set(_CMAKE_REQUIRED_QUIET_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER}         ${CMAKE_REQUIRED_QUIET})
68
69  if (${ARGC} GREATER 0 AND "${ARGV0}" STREQUAL "RESET")
70    cmake_reset_check_state()
71  endif()
72
73endmacro()
74
75macro(CMAKE_POP_CHECK_STATE)
76
77# don't pop more than we pushed
78  if("${_CMAKE_PUSH_CHECK_STATE_COUNTER}" GREATER "0")
79
80    set(CMAKE_EXTRA_INCLUDE_FILES    ${_CMAKE_EXTRA_INCLUDE_FILES_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER}})
81    set(CMAKE_REQUIRED_INCLUDES      ${_CMAKE_REQUIRED_INCLUDES_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER}})
82    set(CMAKE_REQUIRED_DEFINITIONS   ${_CMAKE_REQUIRED_DEFINITIONS_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER}})
83    set(CMAKE_REQUIRED_LINK_OPTIONS  ${_CMAKE_REQUIRED_LINK_OPTIONS_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER}})
84    set(CMAKE_REQUIRED_LIBRARIES     ${_CMAKE_REQUIRED_LIBRARIES_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER}})
85    set(CMAKE_REQUIRED_FLAGS         ${_CMAKE_REQUIRED_FLAGS_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER}})
86    set(CMAKE_REQUIRED_QUIET         ${_CMAKE_REQUIRED_QUIET_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER}})
87
88    math(EXPR _CMAKE_PUSH_CHECK_STATE_COUNTER "${_CMAKE_PUSH_CHECK_STATE_COUNTER}-1")
89  endif()
90
91endmacro()
92