1# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
2# file Copyright.txt or https://cmake.org/licensing for details.
3
4
5# This module is shared by multiple languages; use include blocker.
6if(__COMPILER_CLANG)
7  return()
8endif()
9set(__COMPILER_CLANG 1)
10
11include(Compiler/CMakeCommonCompilerMacros)
12
13set(__pch_header_C "c-header")
14set(__pch_header_CXX "c++-header")
15set(__pch_header_OBJC "objective-c-header")
16set(__pch_header_OBJCXX "objective-c++-header")
17
18if("x${CMAKE_C_SIMULATE_ID}" STREQUAL "xMSVC"
19    OR "x${CMAKE_CXX_SIMULATE_ID}" STREQUAL "xMSVC"
20    OR "x${CMAKE_Fortran_SIMULATE_ID}" STREQUAL "xMSVC")
21  macro(__compiler_clang lang)
22  endmacro()
23else()
24  include(Compiler/GNU)
25
26  macro(__compiler_clang lang)
27    __compiler_gnu(${lang})
28    set(CMAKE_${lang}_COMPILE_OPTIONS_PIE "-fPIE")
29    # Link options for PIE are already set in 'Compiler/GNU.cmake'
30    # but clang may require alternate syntax on some platforms
31    if (APPLE)
32      set(CMAKE_${lang}_LINK_OPTIONS_PIE ${CMAKE_${lang}_COMPILE_OPTIONS_PIE} -Xlinker -pie)
33      set(CMAKE_${lang}_LINK_OPTIONS_NO_PIE -Xlinker -no_pie)
34    endif()
35    set(CMAKE_INCLUDE_SYSTEM_FLAG_${lang} "-isystem ")
36    set(CMAKE_${lang}_COMPILE_OPTIONS_VISIBILITY "-fvisibility=")
37    if(CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 3.4.0)
38      set(CMAKE_${lang}_COMPILE_OPTIONS_TARGET "-target ")
39      set(CMAKE_${lang}_COMPILE_OPTIONS_EXTERNAL_TOOLCHAIN "-gcc-toolchain ")
40    else()
41      set(CMAKE_${lang}_COMPILE_OPTIONS_TARGET "--target=")
42      set(CMAKE_${lang}_COMPILE_OPTIONS_EXTERNAL_TOOLCHAIN "--gcc-toolchain=")
43    endif()
44    set(CMAKE_${lang}_LINKER_WRAPPER_FLAG "-Xlinker" " ")
45    set(CMAKE_${lang}_LINKER_WRAPPER_FLAG_SEP)
46
47    if(CMAKE_${lang}_COMPILER_TARGET)
48      if(CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 3.4.0)
49        list(APPEND CMAKE_${lang}_COMPILER_PREDEFINES_COMMAND "-target" "${CMAKE_${lang}_COMPILER_TARGET}")
50      else()
51        list(APPEND CMAKE_${lang}_COMPILER_PREDEFINES_COMMAND "--target=${CMAKE_${lang}_COMPILER_TARGET}")
52      endif()
53    endif()
54
55    set(_CMAKE_${lang}_IPO_SUPPORTED_BY_CMAKE YES)
56    set(_CMAKE_${lang}_IPO_MAY_BE_SUPPORTED_BY_COMPILER YES)
57
58    string(COMPARE EQUAL "${CMAKE_${lang}_COMPILER_ID}" "AppleClang" __is_apple_clang)
59    string(COMPARE EQUAL "${CMAKE_${lang}_COMPILER_ID}" "FujitsuClang" __is_fujitsu_clang)
60
61    # '-flto=thin' available since Clang 3.9 and Xcode 8
62    # * http://clang.llvm.org/docs/ThinLTO.html#clang-llvm
63    # * https://trac.macports.org/wiki/XcodeVersionInfo
64    set(_CMAKE_LTO_THIN TRUE)
65    if(__is_apple_clang)
66      if(CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 8.0)
67        set(_CMAKE_LTO_THIN FALSE)
68      endif()
69    elseif(__is_fujitsu_clang)
70      set(_CMAKE_LTO_THIN FALSE)
71    else()
72      if(CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 3.9)
73        set(_CMAKE_LTO_THIN FALSE)
74      endif()
75    endif()
76
77    if(_CMAKE_LTO_THIN)
78      set(CMAKE_${lang}_COMPILE_OPTIONS_IPO "-flto=thin")
79    else()
80      set(CMAKE_${lang}_COMPILE_OPTIONS_IPO "-flto")
81    endif()
82
83    if(ANDROID AND NOT CMAKE_ANDROID_NDK_VERSION VERSION_GREATER_EQUAL "22")
84      # https://github.com/android-ndk/ndk/issues/242
85      set(CMAKE_${lang}_LINK_OPTIONS_IPO "-fuse-ld=gold")
86    endif()
87
88    if(ANDROID OR __is_apple_clang)
89      set(__ar "${CMAKE_AR}")
90      set(__ranlib "${CMAKE_RANLIB}")
91    else()
92      set(__ar "${CMAKE_${lang}_COMPILER_AR}")
93      set(__ranlib "${CMAKE_${lang}_COMPILER_RANLIB}")
94    endif()
95
96    set(CMAKE_${lang}_ARCHIVE_CREATE_IPO
97      "\"${__ar}\" cr <TARGET> <LINK_FLAGS> <OBJECTS>"
98    )
99
100    set(CMAKE_${lang}_ARCHIVE_APPEND_IPO
101      "\"${__ar}\" r <TARGET> <LINK_FLAGS> <OBJECTS>"
102    )
103
104    set(CMAKE_${lang}_ARCHIVE_FINISH_IPO
105      "\"${__ranlib}\" <TARGET>"
106    )
107
108    set(CMAKE_PCH_EXTENSION .pch)
109    if (NOT CMAKE_GENERATOR MATCHES "Xcode")
110      set(CMAKE_PCH_PROLOGUE "#pragma clang system_header")
111    endif()
112    if(CMAKE_${lang}_COMPILER_VERSION VERSION_GREATER_EQUAL 11.0.0 AND NOT __is_apple_clang)
113      set(CMAKE_${lang}_COMPILE_OPTIONS_INSTANTIATE_TEMPLATES_PCH -fpch-instantiate-templates)
114    endif()
115    set(CMAKE_${lang}_COMPILE_OPTIONS_USE_PCH -Xclang -include-pch -Xclang <PCH_FILE> -Xclang -include -Xclang <PCH_HEADER>)
116    set(CMAKE_${lang}_COMPILE_OPTIONS_CREATE_PCH -Xclang -emit-pch -Xclang -include -Xclang <PCH_HEADER> -x ${__pch_header_${lang}})
117  endmacro()
118endif()
119
120macro(__compiler_clang_cxx_standards lang)
121  if("x${CMAKE_${lang}_COMPILER_FRONTEND_VARIANT}" STREQUAL "xGNU")
122    if(NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 2.1)
123      set(CMAKE_${lang}98_STANDARD_COMPILE_OPTION "-std=c++98")
124      set(CMAKE_${lang}98_EXTENSION_COMPILE_OPTION "-std=gnu++98")
125    endif()
126
127    if(NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 3.1)
128      set(CMAKE_${lang}98_STANDARD__HAS_FULL_SUPPORT ON)
129      set(CMAKE_${lang}11_STANDARD_COMPILE_OPTION "-std=c++11")
130      set(CMAKE_${lang}11_EXTENSION_COMPILE_OPTION "-std=gnu++11")
131      set(CMAKE_${lang}11_STANDARD__HAS_FULL_SUPPORT ON)
132    elseif(NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 2.1)
133      set(CMAKE_${lang}11_STANDARD_COMPILE_OPTION "-std=c++0x")
134      set(CMAKE_${lang}11_EXTENSION_COMPILE_OPTION "-std=gnu++0x")
135    endif()
136
137    if(NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 3.5)
138      set(CMAKE_${lang}14_STANDARD_COMPILE_OPTION "-std=c++14")
139      set(CMAKE_${lang}14_EXTENSION_COMPILE_OPTION "-std=gnu++14")
140      set(CMAKE_${lang}14_STANDARD__HAS_FULL_SUPPORT ON)
141    elseif(NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 3.4)
142      set(CMAKE_${lang}14_STANDARD_COMPILE_OPTION "-std=c++1y")
143      set(CMAKE_${lang}14_EXTENSION_COMPILE_OPTION "-std=gnu++1y")
144      set(CMAKE_${lang}14_STANDARD__HAS_FULL_SUPPORT ON)
145    endif()
146
147    set(_clang_version_std17 5.0)
148    if(CMAKE_SYSTEM_NAME STREQUAL "Android")
149      set(_clang_version_std17 6.0)
150    endif()
151
152    if (NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS "${_clang_version_std17}")
153      set(CMAKE_${lang}17_STANDARD_COMPILE_OPTION "-std=c++17")
154      set(CMAKE_${lang}17_EXTENSION_COMPILE_OPTION "-std=gnu++17")
155    elseif (NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 3.5)
156      set(CMAKE_${lang}17_STANDARD_COMPILE_OPTION "-std=c++1z")
157      set(CMAKE_${lang}17_EXTENSION_COMPILE_OPTION "-std=gnu++1z")
158    endif()
159
160    if(NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 11.0)
161      set(CMAKE_${lang}20_STANDARD_COMPILE_OPTION "-std=c++20")
162      set(CMAKE_${lang}20_EXTENSION_COMPILE_OPTION "-std=gnu++20")
163    elseif(NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS "${_clang_version_std17}")
164      set(CMAKE_${lang}20_STANDARD_COMPILE_OPTION "-std=c++2a")
165      set(CMAKE_${lang}20_EXTENSION_COMPILE_OPTION "-std=gnu++2a")
166    endif()
167
168    unset(_clang_version_std17)
169
170    if(NOT CMAKE_${lang}_COMPILER_VERSION VERSION_LESS 12.0)
171      set(CMAKE_${lang}23_STANDARD_COMPILE_OPTION "-std=c++2b")
172      set(CMAKE_${lang}23_EXTENSION_COMPILE_OPTION "-std=gnu++2b")
173    endif()
174
175    if("x${CMAKE_${lang}_SIMULATE_ID}" STREQUAL "xMSVC")
176      # The MSVC standard library requires C++14, and MSVC itself has no
177      # notion of operating in a mode not aware of at least that standard.
178      set(CMAKE_${lang}98_STANDARD_COMPILE_OPTION "-std=c++14")
179      set(CMAKE_${lang}98_EXTENSION_COMPILE_OPTION "-std=gnu++14")
180      set(CMAKE_${lang}11_STANDARD_COMPILE_OPTION "-std=c++14")
181      set(CMAKE_${lang}11_EXTENSION_COMPILE_OPTION "-std=gnu++14")
182
183      # This clang++ is missing some features because of MSVC compatibility.
184      unset(CMAKE_${lang}11_STANDARD__HAS_FULL_SUPPORT)
185      unset(CMAKE_${lang}14_STANDARD__HAS_FULL_SUPPORT)
186    endif()
187
188    __compiler_check_default_language_standard(${lang} 2.1 98)
189  elseif(CMAKE_${lang}_COMPILER_VERSION VERSION_GREATER_EQUAL 3.9
190      AND CMAKE_${lang}_SIMULATE_VERSION VERSION_GREATER_EQUAL 19.0)
191    # This version of clang-cl and the MSVC version it simulates have
192    # support for -std: flags.
193    set(CMAKE_${lang}98_STANDARD_COMPILE_OPTION "")
194    set(CMAKE_${lang}98_EXTENSION_COMPILE_OPTION "")
195    set(CMAKE_${lang}98_STANDARD__HAS_FULL_SUPPORT ON)
196    set(CMAKE_${lang}11_STANDARD_COMPILE_OPTION "")
197    set(CMAKE_${lang}11_EXTENSION_COMPILE_OPTION "")
198    set(CMAKE_${lang}14_STANDARD_COMPILE_OPTION "-std:c++14")
199    set(CMAKE_${lang}14_EXTENSION_COMPILE_OPTION "-std:c++14")
200
201    if(CMAKE_${lang}_COMPILER_VERSION VERSION_GREATER_EQUAL 6.0)
202      set(CMAKE_${lang}17_STANDARD_COMPILE_OPTION "-std:c++17")
203      set(CMAKE_${lang}17_EXTENSION_COMPILE_OPTION "-std:c++17")
204    else()
205      set(CMAKE_${lang}17_STANDARD_COMPILE_OPTION "-std:c++latest")
206      set(CMAKE_${lang}17_EXTENSION_COMPILE_OPTION "-std:c++latest")
207    endif()
208
209    if(CMAKE_${lang}_COMPILER_VERSION VERSION_GREATER_EQUAL 13.0)
210      set(CMAKE_${lang}23_STANDARD_COMPILE_OPTION "-std:c++latest")
211      set(CMAKE_${lang}23_EXTENSION_COMPILE_OPTION "-std:c++latest")
212      set(CMAKE_${lang}20_STANDARD_COMPILE_OPTION "-std:c++20")
213      set(CMAKE_${lang}20_EXTENSION_COMPILE_OPTION "-std:c++20")
214    elseif(CMAKE_${lang}_COMPILER_VERSION VERSION_GREATER_EQUAL 6.0)
215      set(CMAKE_${lang}20_STANDARD_COMPILE_OPTION "-std:c++latest")
216      set(CMAKE_${lang}20_EXTENSION_COMPILE_OPTION "-std:c++latest")
217    endif()
218
219    __compiler_check_default_language_standard(${lang} 3.9 14)
220  else()
221    # This version of clang-cl, or the MSVC version it simulates, does not have
222    # language standards.  Set these options as empty strings so the feature
223    # test infrastructure can at least check to see if they are defined.
224    set(CMAKE_${lang}98_STANDARD_COMPILE_OPTION "")
225    set(CMAKE_${lang}98_EXTENSION_COMPILE_OPTION "")
226    set(CMAKE_${lang}11_STANDARD_COMPILE_OPTION "")
227    set(CMAKE_${lang}11_EXTENSION_COMPILE_OPTION "")
228    set(CMAKE_${lang}14_STANDARD_COMPILE_OPTION "")
229    set(CMAKE_${lang}14_EXTENSION_COMPILE_OPTION "")
230    set(CMAKE_${lang}17_STANDARD_COMPILE_OPTION "")
231    set(CMAKE_${lang}17_EXTENSION_COMPILE_OPTION "")
232    set(CMAKE_${lang}20_STANDARD_COMPILE_OPTION "")
233    set(CMAKE_${lang}20_EXTENSION_COMPILE_OPTION "")
234    set(CMAKE_${lang}23_STANDARD_COMPILE_OPTION "")
235    set(CMAKE_${lang}23_EXTENSION_COMPILE_OPTION "")
236
237    # There is no meaningful default for this
238    set(CMAKE_${lang}_STANDARD_DEFAULT "")
239
240    # There are no compiler modes so we only need to test features once.
241    # Override the default macro for this special case.  Pretend that
242    # all language standards are available so that at least compilation
243    # can be attempted.
244    macro(cmake_record_${lang}_compile_features)
245      list(APPEND CMAKE_${lang}_COMPILE_FEATURES
246        cxx_std_98
247        cxx_std_11
248        cxx_std_14
249        cxx_std_17
250        cxx_std_20
251        cxx_std_23
252        )
253      _record_compiler_features(${lang} "" CMAKE_${lang}_COMPILE_FEATURES)
254    endmacro()
255  endif()
256endmacro()
257