1# This file is processed when the IAR C++ Compiler is used
2#
3# C++ Language Specification support
4#  - Newer versions of the IAR C++ Compiler require the --c++ flag to build a C++ file.
5#    Earlier versions for non-ARM architectures provided Embedded C++, enabled with the --eec++ flag.
6#
7# The IAR Language Extensions
8#  - The IAR Language Extensions can be enabled by -e flag
9#
10include(Compiler/IAR)
11include(Compiler/CMakeCommonCompilerMacros)
12
13if(NOT DEFINED CMAKE_CXX_COMPILER_VERSION)
14  message(FATAL_ERROR "CMAKE_CXX_COMPILER_VERSION not detected. This should be automatic.")
15endif()
16
17# Whenever needed, override this default behavior using CMAKE_IAR_CXX_FLAG in your toolchain file.
18if(NOT CMAKE_IAR_CXX_FLAG)
19  set(_CMAKE_IAR_MODERNCXX_LIST 14 17)
20  if(${CMAKE_CXX_STANDARD_COMPUTED_DEFAULT} IN_LIST _CMAKE_IAR_MODERNCXX_LIST OR
21     ("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "ARM" AND ${CMAKE_CXX_STANDARD_COMPUTED_DEFAULT} EQUAL 98))
22    string(PREPEND CMAKE_CXX_FLAGS "--c++ ")
23  else()
24    string(PREPEND CMAKE_CXX_FLAGS "--eec++ ")
25  endif()
26  unset(_CMAKE_IAR_MODERNCXX_LIST)
27endif()
28
29set(CMAKE_CXX_STANDARD_COMPILE_OPTION "")
30set(CMAKE_CXX_EXTENSION_COMPILE_OPTION -e) # Unused after CMP0128
31
32set(CMAKE_CXX${CMAKE_CXX_STANDARD_COMPUTED_DEFAULT}_STANDARD_COMPILE_OPTION "")
33set(CMAKE_CXX${CMAKE_CXX_STANDARD_COMPUTED_DEFAULT}_EXTENSION_COMPILE_OPTION -e)
34
35# Architecture specific
36if("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "ARM")
37  if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 5)
38    # IAR C++ Compiler for Arm prior version 5.xx uses XLINK. Support in CMake is not implemented.
39    message(FATAL_ERROR "IAR C++ Compiler for Arm version ${CMAKE_CXX_COMPILER_VERSION} not supported by CMake.")
40  endif()
41  __compiler_iar_ilink(CXX)
42  __compiler_check_default_language_standard(CXX 5.10 98 8.10 14 8.40 17)
43
44elseif("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "RX")
45  __compiler_iar_ilink(CXX)
46  __compiler_check_default_language_standard(CXX 2.10 98 4.10 14 4.20 17)
47
48elseif("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "RH850")
49  __compiler_iar_ilink(CXX)
50  __compiler_check_default_language_standard(CXX 1.10 98 2.10 14 2.21 17)
51
52elseif("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "RL78")
53  if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 2)
54    # # IAR C++ Compiler for RL78 prior version 2.xx uses XLINK. Support in CMake is not implemented.
55    message(FATAL_ERROR "IAR C++ Compiler for RL78 version ${CMAKE_CXX_COMPILER_VERSION} not supported by CMake.")
56  endif()
57  __compiler_iar_ilink(CXX)
58  __compiler_check_default_language_standard(CXX 2.10 98 4.10 14 4.20 17)
59
60elseif("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "RISCV")
61  __compiler_iar_ilink(CXX)
62  __compiler_check_default_language_standard(CXX 1.10 98 1.10 14 1.21 17)
63
64elseif("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "AVR")
65  __compiler_iar_xlink(CXX)
66  __compiler_check_default_language_standard(CXX 7.10 98)
67
68elseif("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "MSP430")
69  __compiler_iar_xlink(CXX)
70  __compiler_check_default_language_standard(CXX 5.10 98)
71  set(CMAKE_CXX_OUTPUT_EXTENSION ".r43")
72
73elseif("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "V850")
74  __compiler_iar_xlink(CXX)
75  __compiler_check_default_language_standard(CXX 1.10 98)
76  set(CMAKE_C_OUTPUT_EXTENSION ".r85")
77
78elseif("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "8051")
79  __compiler_iar_xlink(CXX)
80  __compiler_check_default_language_standard(CXX 6.10 98)
81  set(CMAKE_C_OUTPUT_EXTENSION ".r51")
82
83elseif("${CMAKE_CXX_COMPILER_ARCHITECTURE_ID}" STREQUAL "STM8")
84  __compiler_iar_ilink(CXX)
85  __compiler_check_default_language_standard(CXX 3.11 98)
86
87else()
88  message(FATAL_ERROR "CMAKE_CXX_COMPILER_ARCHITECTURE_ID not detected. This should be automatic." )
89endif()
90