1include(Compiler/TI)
2__compiler_ti(C)
3
4# Architecture specific
5# C99 versions: https://processors.wiki.ti.com/index.php/C99_Support_in_TI_Compilers
6
7if("${CMAKE_C_COMPILER_ARCHITECTURE_ID}" STREQUAL "ARM")
8  set(__COMPILER_TI_C99_VERSION_ARM 5.2)
9  set(__COMPILER_TI_C11_VERSION_ARM 18.12)
10
11elseif("${CMAKE_C_COMPILER_ARCHITECTURE_ID}" STREQUAL "MSP430")
12  set(__COMPILER_TI_C99_VERSION_MSP430 4.3)
13  set(__COMPILER_TI_C11_VERSION_MSP430 18.12)
14
15elseif("${CMAKE_C_COMPILER_ARCHITECTURE_ID}" STREQUAL "TMS320C28x")
16  set(__COMPILER_TI_C99_VERSION_TMS320C28x 6.3)
17  set(__COMPILER_TI_C11_VERSION_TMS320C28x 18.9)
18
19elseif("${CMAKE_C_COMPILER_ARCHITECTURE_ID}" STREQUAL "TMS320C6x")
20  set(__COMPILER_TI_C99_VERSION_TMS320C6x 7.5)
21
22else()
23  # architecture not handled
24  return()
25
26endif()
27
28
29if(CMAKE_C_COMPILER_VERSION VERSION_GREATER_EQUAL "${__COMPILER_TI_C99_VERSION_${CMAKE_C_COMPILER_ARCHITECTURE_ID}}")
30
31  set(CMAKE_C90_STANDARD_COMPILE_OPTION "--c89" "--strict_ansi")
32  set(CMAKE_C90_EXTENSION_COMPILE_OPTION "--c89" "--relaxed_ansi")
33
34  set(CMAKE_C99_STANDARD_COMPILE_OPTION "--c99" "--strict_ansi")
35  set(CMAKE_C99_EXTENSION_COMPILE_OPTION "--c99" "--relaxed_ansi")
36
37  if(DEFINED __COMPILER_TI_C11_VERSION_${CMAKE_C_COMPILER_ARCHITECTURE_ID} AND
38     CMAKE_C_COMPILER_VERSION VERSION_GREATER_EQUAL "${__COMPILER_TI_C11_VERSION_${CMAKE_C_COMPILER_ARCHITECTURE_ID}}")
39
40    set(CMAKE_C11_STANDARD_COMPILE_OPTION "--c11" "--strict_ansi")
41    set(CMAKE_C11_EXTENSION_COMPILE_OPTION "--c11" "--relaxed_ansi")
42
43  endif()
44
45else()
46
47  set(CMAKE_C90_STANDARD_COMPILE_OPTION "--strict_ansi")
48  set(CMAKE_C90_EXTENSION_COMPILE_OPTION "--relaxed_ansi")
49
50endif()
51
52
53# Architecture specific
54
55if("${CMAKE_C_COMPILER_ARCHITECTURE_ID}" STREQUAL "ARM")
56  __compiler_check_default_language_standard(C 2.0 90)
57
58elseif("${CMAKE_C_COMPILER_ARCHITECTURE_ID}" STREQUAL "MSP430")
59  __compiler_check_default_language_standard(C 3.0 90)
60
61elseif("${CMAKE_C_COMPILER_ARCHITECTURE_ID}" STREQUAL "TMS320C28x")
62  __compiler_check_default_language_standard(C 4.1 90)
63
64elseif("${CMAKE_C_COMPILER_ARCHITECTURE_ID}" STREQUAL "TMS320C6x")
65  __compiler_check_default_language_standard(C 4.45 90)
66
67endif()
68