1# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
2# file Copyright.txt or https://cmake.org/licensing for details.
3
4#[=======================================================================[.rst:
5FindArmadillo
6-------------
7
8Find the Armadillo C++ library.
9Armadillo is a library for linear algebra & scientific computing.
10
11.. versionadded:: 3.18
12  Support for linking wrapped libraries directly (``ARMA_DONT_USE_WRAPPER``).
13
14Using Armadillo:
15
16::
17
18  find_package(Armadillo REQUIRED)
19  include_directories(${ARMADILLO_INCLUDE_DIRS})
20  add_executable(foo foo.cc)
21  target_link_libraries(foo ${ARMADILLO_LIBRARIES})
22
23This module sets the following variables:
24
25::
26
27  ARMADILLO_FOUND - set to true if the library is found
28  ARMADILLO_INCLUDE_DIRS - list of required include directories
29  ARMADILLO_LIBRARIES - list of libraries to be linked
30  ARMADILLO_VERSION_MAJOR - major version number
31  ARMADILLO_VERSION_MINOR - minor version number
32  ARMADILLO_VERSION_PATCH - patch version number
33  ARMADILLO_VERSION_STRING - version number as a string (ex: "1.0.4")
34  ARMADILLO_VERSION_NAME - name of the version (ex: "Antipodean Antileech")
35#]=======================================================================]
36
37find_path(ARMADILLO_INCLUDE_DIR
38  NAMES armadillo
39  PATHS "$ENV{ProgramFiles}/Armadillo/include"
40  )
41mark_as_advanced(ARMADILLO_INCLUDE_DIR)
42
43if(ARMADILLO_INCLUDE_DIR)
44  # ------------------------------------------------------------------------
45  #  Extract version information from <armadillo>
46  # ------------------------------------------------------------------------
47
48  # WARNING: Early releases of Armadillo didn't have the arma_version.hpp file.
49  # (e.g. v.0.9.8-1 in ubuntu maverick packages (2001-03-15))
50  # If the file is missing, set all values to 0
51  set(ARMADILLO_VERSION_MAJOR 0)
52  set(ARMADILLO_VERSION_MINOR 0)
53  set(ARMADILLO_VERSION_PATCH 0)
54  set(ARMADILLO_VERSION_NAME "EARLY RELEASE")
55
56  if(EXISTS "${ARMADILLO_INCLUDE_DIR}/armadillo_bits/arma_version.hpp")
57
58    # Read and parse armdillo version header file for version number
59    file(STRINGS "${ARMADILLO_INCLUDE_DIR}/armadillo_bits/arma_version.hpp" _ARMA_HEADER_CONTENTS REGEX "#define ARMA_VERSION_[A-Z]+ ")
60    string(REGEX REPLACE ".*#define ARMA_VERSION_MAJOR ([0-9]+).*" "\\1" ARMADILLO_VERSION_MAJOR "${_ARMA_HEADER_CONTENTS}")
61    string(REGEX REPLACE ".*#define ARMA_VERSION_MINOR ([0-9]+).*" "\\1" ARMADILLO_VERSION_MINOR "${_ARMA_HEADER_CONTENTS}")
62    string(REGEX REPLACE ".*#define ARMA_VERSION_PATCH ([0-9]+).*" "\\1" ARMADILLO_VERSION_PATCH "${_ARMA_HEADER_CONTENTS}")
63
64    # WARNING: The number of spaces before the version name is not one.
65    string(REGEX REPLACE ".*#define ARMA_VERSION_NAME\ +\"([0-9a-zA-Z\ _-]+)\".*" "\\1" ARMADILLO_VERSION_NAME "${_ARMA_HEADER_CONTENTS}")
66
67  endif()
68
69  set(ARMADILLO_VERSION_STRING "${ARMADILLO_VERSION_MAJOR}.${ARMADILLO_VERSION_MINOR}.${ARMADILLO_VERSION_PATCH}")
70endif ()
71
72if(EXISTS "${ARMADILLO_INCLUDE_DIR}/armadillo_bits/config.hpp")
73  file(STRINGS "${ARMADILLO_INCLUDE_DIR}/armadillo_bits/config.hpp" _ARMA_CONFIG_CONTENTS REGEX "^#define ARMA_USE_[A-Z]+")
74  string(REGEX MATCH "ARMA_USE_WRAPPER" _ARMA_USE_WRAPPER "${_ARMA_CONFIG_CONTENTS}")
75  string(REGEX MATCH "ARMA_USE_LAPACK" _ARMA_USE_LAPACK "${_ARMA_CONFIG_CONTENTS}")
76  string(REGEX MATCH "ARMA_USE_BLAS" _ARMA_USE_BLAS "${_ARMA_CONFIG_CONTENTS}")
77  string(REGEX MATCH "ARMA_USE_ARPACK" _ARMA_USE_ARPACK "${_ARMA_CONFIG_CONTENTS}")
78  string(REGEX MATCH "ARMA_USE_HDF5" _ARMA_USE_HDF5 "${_ARMA_CONFIG_CONTENTS}")
79endif()
80
81include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
82
83# If _ARMA_USE_WRAPPER is set, then we just link to armadillo, but if it's not then we need support libraries instead
84set(_ARMA_SUPPORT_LIBRARIES)
85
86if(_ARMA_USE_WRAPPER)
87  # Link to the armadillo wrapper library.
88  find_library(ARMADILLO_LIBRARY
89    NAMES armadillo
90    NAMES_PER_DIR
91    PATHS
92      "$ENV{ProgramFiles}/Armadillo/lib"
93      "$ENV{ProgramFiles}/Armadillo/lib64"
94      "$ENV{ProgramFiles}/Armadillo"
95    )
96  mark_as_advanced(ARMADILLO_LIBRARY)
97  set(_ARMA_REQUIRED_VARS ARMADILLO_LIBRARY)
98else()
99  # Link directly to individual components.
100  set(ARMADILLO_LIBRARY "")
101  foreach(pkg
102      LAPACK
103      BLAS
104      ARPACK
105      HDF5
106      )
107    if(_ARMA_USE_${pkg})
108      find_package(${pkg} QUIET)
109      list(APPEND _ARMA_REQUIRED_VARS "${pkg}_FOUND")
110      if(${pkg}_FOUND)
111        list(APPEND _ARMA_SUPPORT_LIBRARIES ${${pkg}_LIBRARIES})
112      endif()
113    endif()
114  endforeach()
115endif()
116
117find_package_handle_standard_args(Armadillo
118  REQUIRED_VARS ARMADILLO_INCLUDE_DIR ${_ARMA_REQUIRED_VARS}
119  VERSION_VAR ARMADILLO_VERSION_STRING)
120
121if (ARMADILLO_FOUND)
122  set(ARMADILLO_INCLUDE_DIRS ${ARMADILLO_INCLUDE_DIR})
123  set(ARMADILLO_LIBRARIES ${ARMADILLO_LIBRARY} ${_ARMA_SUPPORT_LIBRARIES})
124endif ()
125
126# Clean up internal variables
127unset(_ARMA_REQUIRED_VARS)
128unset(_ARMA_SUPPORT_LIBRARIES)
129unset(_ARMA_USE_WRAPPER)
130unset(_ARMA_USE_LAPACK)
131unset(_ARMA_USE_BLAS)
132unset(_ARMA_USE_ARPACK)
133unset(_ARMA_USE_HDF5)
134unset(_ARMA_CONFIG_CONTENTS)
135unset(_ARMA_HEADER_CONTENTS)
136